意外と簡単な Adblock Plus のフィルターにチェックサムを入れる方法

備忘録も兼ねてメモっておく

前提

• Perl 実行環境（PHP のサンプルコードも載ってたけどここでは割愛）
• フィルタのエンコーディングを UTF-8 にしておく

スクリプト

• https://hg.adblockplus.org/adblockplus/file/tip/addChecksum.pl の右上「raw」リンクからダウンロード

ファイル内容（私が書いたスクリプトではない）はこのエントリー末尾に引用した

ファイルヘッダに書かれている通りに実行するだけ

perl addChecksum.pl YourFilter.txt 

めちゃ簡単！ちなみに、

• • 出力されるファイルの改行文字は Unix 等でおなじみの LF（CR は削除される）

参考：Checksum 付加する Perl スクリプト

解説する必要ないけど、流れだけメモ

1. 1. ファイルを読み込み
   2. 古い Checksum を含む行を消す
   3. CR 消す
   4. 連続した改行を１つにまとめる
   5. 上記を処理後、md5_base64 関数で MD5 算出
   6. ２行目に Checksum 挿入
   7. ファイル書きだし

以下、参考までに 2010-02-08 03:00 JST 時点のファイル内容そのまま

#!/usr/bin/perl

#############################################################################
# This is a reference script to add checksums to downloadable               #
# subscriptions. The checksum will be validated by Adblock Plus on download #
# and checksum mismatches (broken downloads) will be rejected.              #
#                                                                           #
# To add a checksum to a subscription file, run the script like this:       #
#                                                                           #
#   perl addChecksum.pl subscription.txt                                    #
#                                                                           #
# Note: your subscription file should be saved in UTF-8 encoding, otherwise #
# the generated checksum might be incorrect.                                #
#                                                                           #
#############################################################################

use strict;
use warnings;
use Digest::MD5 qw(md5_base64);

die "Usage: $^X $0 subscription.txt\n" unless @ARGV;

my $file = $ARGV[0];
my $data = readFile($file);

# Remove already existing checksum
$data =~ s/^.*!\s*checksum[\s\-:]+([\w\+\/=]+).*\n//gmi;

# Calculate new checksum: remove all CR symbols and empty
# lines and get an MD5 checksum of the result (base64-encoded,
# without the trailing = characters).
my $checksumData = $data;
$checksumData =~ s/\r//g;
$checksumData =~ s/\n+/\n/g;

# Calculate new checksum
my $checksum = md5_base64($checksumData);

# Insert checksum into the file
$data =~ s/(\r?\n)/$1! Checksum: $checksum$1/;

writeFile($file, $data);

sub readFile
{
  my $file = shift;

  open(local *FILE, "<", $file) || die "Could not read file '$file'";
  binmode(FILE);
  local $/;
  my $result = <FILE>;
  close(FILE);

  return $result;
}

sub writeFile
{
  my ($file, $contents) = @_;

  open(local *FILE, ">", $file) || die "Could not write file '$file'";
  binmode(FILE);
  print FILE $contents;
  close(FILE);
}